view demo/metaform.ur @ 1023:e46227efcbba

Bidding interface
author Adam Chlipala <adamc@hcoop.net>
date Sun, 01 Nov 2009 10:20:20 -0500
parents 669ac5e9a69e
children 8d3aa6c7cee0
line wrap: on
line source
functor Make (M : sig
                  con fs :: {Unit}
                  val fl : folder fs
                  val names : $(mapU string fs)
              end) = struct

    fun handler values = return <xml><body>
      {foldURX2 [string] [string] [body]
       (fn [nm :: Name] [rest :: {Unit}] [[nm] ~ rest] name value => <xml>
         <li> {[name]} = {[value]}</li>
       </xml>)
       [M.fs] M.fl M.names values}
    </body></xml>

    fun main () = return <xml><body>
      <form>
        {foldUR [string] [fn cols :: {Unit} => xml form [] (mapU string cols)]
                (fn [nm :: Name] [rest :: {Unit}] [[nm] ~ rest] name
                                 (acc : xml form [] (mapU string rest)) => <xml>
                                   <li> {[name]}: <textbox{nm}/></li>
                                   {useMore acc}
                                 </xml>)
                <xml/>
                [M.fs] M.fl M.names}
        <submit action={handler}/>
      </form>
    </body></xml>

end