view demo/metaform.ur @ 1151:de48dc2c9ee8

Allow .urp files without initial blank lines
author Adam Chlipala <adamc@hcoop.net>
date Sat, 06 Feb 2010 15:34:41 -0500
parents 8d3aa6c7cee0
children 51e596feec37
line wrap: on
line source
functor Make (M : sig
                  con fs :: {Unit}
                  val fl : folder fs
                  val names : $(mapU string fs)
              end) = struct

    fun handler values = return <xml><body>
      {@foldURX2 [string] [string] [body]
        (fn [nm :: Name] [rest :: {Unit}] [[nm] ~ rest] name value => <xml>
          <li> {[name]} = {[value]}</li>
        </xml>)
        M.fl M.names values}
    </body></xml>

    fun main () = return <xml><body>
      <form>
        {@foldUR [string] [fn cols :: {Unit} => xml form [] (mapU string cols)]
          (fn [nm :: Name] [rest :: {Unit}] [[nm] ~ rest] name
                           (acc : xml form [] (mapU string rest)) => <xml>
                             <li> {[name]}: <textbox{nm}/></li>
                             {useMore acc}
                           </xml>)
          <xml/>
          M.fl M.names}
        <submit action={handler}/>
      </form>
    </body></xml>

end