Mercurial > urweb

view demo/listFun.ur @ 1949:d7bec4e63415

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Do a bit of extra userspace copying to send HTTP response with a single system call
author Adam Chlipala <adam@chlipala.net>
date Tue, 31 Dec 2013 09:34:41 -0500
parents 7ef4b2911b09
children
line wrap: on
line source
open List

functor Make(M : sig
                 type t
                 val toString : t -> string
                 val fromString : string -> option t
             end) = struct
    fun toXml (ls : list M.t) =
        case ls of
            Nil => <xml>[]</xml>
          | Cons (x, ls') => <xml>{[M.toString x]} :: {toXml ls'}</xml>
      
    fun console (ls : list M.t) =
        let
            fun cons (r : {X : string}) =
                case M.fromString r.X of
                    None => return <xml><body>Invalid string!</body></xml>
                  | Some v => console (Cons (v, ls))
        in
            return <xml><body>
              Current list: {toXml ls}<br/>
              Reversed list: {toXml (rev ls)}<br/>
              Length: {[length ls]}<br/>
              <br/>

              <form>
                Add element: <textbox{#X}/> <submit action={cons}/>
              </form>
            </body></xml>
        end

    fun main () = console Nil
end