Mercurial > urweb

view tests/div.ur @ 1893:9a1097954188

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
compileC: Link libraries in the right order This is needed, at least on recent Ubuntu, to fix this linker error when compiling any Ur/Web application: ld: /tmp/webapp.o: undefined reference to symbol 'uw_write' Signed-off-by: Anders Kaseorg <andersk@mit.edu> --- src/compiler.sml | 2 +- 1 file changed, 1 insertion(+), 1 deletion(-)
author Anders Kaseorg <andersk@mit.edu>
date Thu, 21 Nov 2013 14:32:11 -0500
parents 15e0c935c91b
children
line wrap: on
line source
functor Make(M : sig
                 type t
                 val read_t : read t
                 val show_t : show t
                 val num_t : num t
             end) = struct
    fun calculate (n1, n2) = return <xml><body>
      {[readError n1 / readError n2 : M.t]}<br/>
      {[readError n1 % readError n2 : M.t]}<br/>
    </body></xml>

    fun main () =
        s1 <- source "";
        s2 <- source "";
        s3 <- source "";
        s4 <- source "";
        return <xml><body>
          <h1>Client-side</h1>

          <ctextbox source={s1}/> / <ctextbox source={s2}/>
          <button value="=" onclick={n1 <- get s1;
                                     n2 <- get s2;
                                     set s3 (show (readError n1 / readError n2 : M.t));
                                     set s4 (show (readError n1 % readError n2 : M.t))}/>
          <dyn signal={n <- signal s3; return (txt n)}/>,
          <dyn signal={n <- signal s4; return (txt n)}/>

          <h1>Server-side</h1>

          <form>
            <textbox{#1}/> / <textbox{#2}/>
            <submit value="=" action={calculate}/>
          </form>
        </body></xml>
end

structure Int = Make(struct type t = int end)
structure Float = Make(struct type t = float end)

fun main () : transaction page = return <xml><body>
  <li><a link={Int.main ()}>Int</a></li>
  <li><a link={Float.main ()}>Float</a></li>
</body></xml>