Mercurial > urweb

view demo/cookie.ur @ 2166:8a01e8f21de9

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Make OpenSSL usage thread-safe (closes #206) Enable OpenSSL?s multithreading support by defining locking and thread-ID callbacks. Remove a lock obviated by this change.
author Benjamin Barenblat <bbaren@mit.edu>
date Thu, 06 Aug 2015 10:15:53 -0400
parents 93315ac00394
children
line wrap: on
line source
cookie c : {A : string, B : float, C : int}

fun set r =
    setCookie c {Value = {A = r.A, B = readError r.B, C = readError r.C},
                 Expires = None,
                 Secure = False};
    return <xml>Cookie set.</xml>

fun setExp r =
    setCookie c {Value = {A = r.A, B = readError r.B, C = readError r.C},
                 Expires = Some (readError "2012-11-6 00:00:00"),
                 Secure = False};
    return <xml>Cookie set robustly.</xml>

fun delete () =
    clearCookie c;
    return <xml>Cookie cleared.</xml>

fun main () =
    ro <- getCookie c;
    return <xml><body>
      {case ro of
           None => <xml>No cookie set.</xml>
         | Some v => <xml>
           Cookie: A = {[v.A]}, B = {[v.B]}, C = {[v.C]}<br/>
           <form><submit value="Delete" action={delete}/></form>
         </xml>}
      <br/><br/>

      <form>
        A: <textbox{#A}/><br/>
        B: <textbox{#B}/><br/>
        C: <textbox{#C}/><br/>
        <submit action={set}/>
      </form><br/>

      <form>
        <b>Version that expires on November 6, 2012:</b><br/>
        A: <textbox{#A}/><br/>
        B: <textbox{#B}/><br/>
        C: <textbox{#C}/><br/>
        <submit action={setExp}/>
      </form>
    </body></xml>