view demo/treeFun.ur @ 697:755a71c99be5

Threads demo
author Adam Chlipala <adamc@hcoop.net>
date Sun, 05 Apr 2009 10:48:11 -0400
parents 20fab0e96217
children 1fb318c17546
line wrap: on
line source
functor Make(M : sig
                 type key
                 con id :: Name
                 con parent :: Name
                 con cols :: {Type}
                 constraint [id] ~ [parent]
                 constraint [id, parent] ~ cols

                 val key_inj : sql_injectable key
                 val option_key_inj : sql_injectable (option key)

                 table tab : [id = key, parent = option key] ++ cols
             end) = struct

    open M

    fun tree (f : $([id = key, parent = option key] ++ cols) -> xbody)
             (root : option M.key) =
        let
            fun recurse (root : option key) =
                queryX' (SELECT * FROM tab WHERE {eqNullable' (SQL tab.{parent}) root})
                        (fn r =>
                            children <- recurse (Some r.Tab.id);
                            return <xml>
                              <li> {f r.Tab}</li>
                              
                              <ul>
                                {children}
                              </ul>
                            </xml>)
        in
            recurse root
        end

end