Mercurial > urweb

view demo/nested.ur @ 1909:659d1f4e95bf

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
make dist: Use fewer wildcards The remaining ones only work by accident: http://www.gnu.org/software/automake/manual/html_node/Wildcards.html and they have some practical problems too (we don?t really want to distribute include/urweb/config.h or src/config.sml), but this is enough for now to pass ?make distcheck? as long as we don?t run it from a separate build directory. Signed-off-by: Anders Kaseorg <andersk@mit.edu> --- Makefile.am | 6 +++--- src/c/Makefile.am | 2 +- 2 files changed, 4 insertions(+), 4 deletions(-)
author Anders Kaseorg <andersk@mit.edu>
date Fri, 22 Nov 2013 09:36:14 -0500
parents d4a81273d4b1
children
line wrap: on
line source
fun pageA () = return <xml>
  <head>
    <title>A</title>
  </head>
  <body>
    <form>
      <table>
        <tr>
          <td>Forename:</td>
          <td><textbox{#Forename}/></td>
        </tr>
        <tr>
          <td>Enter a Surname?</td>
          <td><checkbox{#EnterSurname}/></td>
        </tr>
      </table>
      <submit action={fromA} />
    </form>
  </body>
</xml>

and fromA r =
    let
        val forename = r.Forename

        fun pageB () = return <xml>
          <head>
            <title>B</title>
          </head>
          <body>
            <form>
              Surname:
              <textbox{#Surname}/>
              <submit action={pageC'} />
            </form>
            <a link={pageA ()}>Previous</a>
          </body>
        </xml>

        and pageC' r = pageC (Some r.Surname)

        and pageC surname = return <xml>
          <head>
            <title>C</title>
          </head>
          <body>
            <p>Hello {[forename]}{case surname of
                                      None => <xml/>
                                    | Some s => <xml> {[s]}</xml>}</p>
            {case surname of
                 None => <xml><a link={pageA ()}>Previous</a></xml>
               | Some _ => <xml><a link={pageB ()}>Previous</a></xml>}
          </body>
        </xml>
    in
        if r.EnterSurname then
            pageB ()
        else
            pageC None
    end

val main = pageA