Mercurial > urweb

view demo/metaform.ur @ 2142:3288e3c9948b

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Fix XML indentation in Emacs mode The return value of MATCH-STRING is a string. At least on Emacs 25, the comparisons between string and character with EQUAL could never succeed, and so the cases for matching braces were never triggered. GET-TEXT-PROPERTY may return a list rather than an atom (for example, on long lines with whitespace-mode turned on), and this broke the heuristic of looking for the tag face in previous text.
author Julian Squires <julian@cipht.net>
date Mon, 04 May 2015 14:35:07 -0400
parents c7b9a33c26c8
children
line wrap: on
line source
functor Make (M : sig
                  con fs :: {Unit}
                  val fl : folder fs
                  val names : $(mapU string fs)
              end) = struct

    fun handler values = return <xml><body>
      {@mapUX2 [string] [string] [body]
        (fn [nm :: Name] [rest ::_] [[nm] ~ rest] name value => <xml>
          <li> {[name]} = {[value]}</li>
        </xml>)
        M.fl M.names values}
    </body></xml>

    fun main () = return <xml><body>
      <form>
        {@foldUR [string] [fn cols => xml form [] (mapU string cols)]
          (fn [nm :: Name] [rest ::_] [[nm] ~ rest] name acc => <xml>
            <li> {[name]}: <textbox{nm}/></li>
            {useMore acc}
          </xml>)
          <xml/>
          M.fl M.names}
        <submit action={handler}/>
      </form>
    </body></xml>

end