view demo/broadcast.ur @ 709:0406e9cccb72

FOREIGN KEY, without ability to link NULL to NOT NULL (and with some lingering problems in row inference)
author Adam Chlipala <>
date Tue, 07 Apr 2009 18:47:47 -0400
parents 1a317a707d71
line wrap: on
line source
functor Make(M : sig type t end) = struct
    sequence s
    table t : {Id : int, Client : client, Channel : channel M.t}
      PRIMARY KEY (Id, Client)

    type topic = int

    val inj : sql_injectable topic = _

    val create = nextval s

    fun subscribe id =
        cli <- self;
        ro <- oneOrNoRows (SELECT t.Channel FROM t WHERE t.Id = {[id]} AND t.Client = {[cli]});
        case ro of
            None =>
            ch <- channel;
            dml (INSERT INTO t (Id, Client, Channel) VALUES ({[id]}, {[cli]}, {[ch]}));
            return ch
          | Some r => return r.T.Channel

    fun send id msg =
        queryI (SELECT t.Channel FROM t WHERE t.Id = {[id]})
        (fn r => Basis.send r.T.Channel msg)

    fun subscribers id =
        r <- oneRow (SELECT COUNT( * ) AS N FROM t WHERE t.Id = {[id]});
        return r.N