Mercurial > urweb

comparison lib/ur/mem.ur @ 1180:ac3dbbc85c6e

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Standard library moduls Incl and Mem; tweaks to Especialize and Unpoly
author Adam Chlipala <adamc@hcoop.net>
date Sat, 06 Mar 2010 16:15:26 -0500
parents
children 0b1d666bddb4
comparison
equal deleted inserted replaced
1179:c58453683bbb 1180:ac3dbbc85c6e
1 con mem' = K ==> fn (nm :: Name) (t :: K) (r :: {K}) (r' :: {K}) =>
2 [[nm] ~ r'] => {Expose : f :: ({K} -> Type) -> f r -> f ([nm = t] ++ r'),
3 Hide : f :: ({K} -> Type) -> f ([nm = t] ++ r') -> f r}
4
5 con mem = K ==> fn (nm :: Name) (t :: K) (r :: {K}) =>
6 tp :: Type -> (r' :: {K} -> [[nm] ~ r'] => mem' nm t r r' -> tp) -> tp
7
8 fun mem [K] [nm :: Name] [t :: K] [r :: {K}] [[nm] ~ r] =
9 fn [tp :: Type] (f : r' :: {K} -> [[nm] ~ r'] => mem' nm t ([nm = t] ++ r) r' -> tp) =>
10 f [r] ! (fn [[nm] ~ r] => {Expose = fn [f :: {K} -> Type] x => x,
11 Hide = fn [f :: {K} -> Type] x => x})
12
13 fun mp [K] [K2] [f :: K -> K2] [nm ::: Name] [t ::: K] [r ::: {K}] (m : mem nm t r) =
14 m [mem nm (f t) (map f r)] (fn [r' :: {K}] [[nm] ~ r'] (m' : mem' nm t r r') =>
15 fn [tp :: Type] (f : r' :: {K2} -> [[nm] ~ r'] =>
16 mem' nm (f t) (map f r) r' -> tp) =>
17 f [map f r'] ! (fn [[nm] ~ map f r'] =>
18 {Expose = fn [f' :: {K2} -> Type] x =>
19 m'.Expose [fn r => f' (map f r)] x,
20 Hide = fn [f' :: {K2} -> Type] x =>
21 m'.Hide [fn r => f' (map f r)] x}))
22
23 fun proj [nm ::: Name] [t ::: Type] [r ::: {Type}] (m : mem nm t r) (r : $r) =
24 m [t] (fn [r' :: {Type}] [[nm] ~ r'] (m' : mem' nm t r r') =>
25 (m'.Expose [fn r => $r] r).nm)
26
27 fun replace [nm ::: Name] [t ::: Type] [r ::: {Type}] (m : mem nm t r) (r : $r) (v : t) =
28 m [$r] (fn [r' :: {Type}] [[nm] ~ r'] (m' : mem' nm t r r') =>
29 m'.Hide [fn r => $r] (m'.Expose [fn r => $r] r -- nm ++ {nm = v}))
30
31 fun fold [K] [tf :: ({K} -> Type)] [r ::: {K}]
32 (f : nm :: Name -> v :: K -> r' :: {K} -> [[nm] ~ r']
33 => mem nm v r -> tf r' -> tf ([nm = v] ++ r'))
34 (i : tf []) (fl : folder r) =
35 @@Incl.fold [tf] [r]
36 (fn [nm :: Name] [v :: K] [r' :: {K}] [[nm] ~ r'] (i : Incl.incl ([nm = v] ++ r') r) acc =>
37 f [nm] [v] [r'] ! (Incl.inv1 [nm] [r'] [r] [mem] i mem) acc)
38 i fl